AutoHotkey

[God of Cheating]

Jeg ville egentlig have posted det her for noget tid siden, men jeg har haft travlt med at spille livet ud af Black Ops.

For noget tid siden nu, mens jeg surfede rundt på nettet, fandt jeg dette dejlige program kaldet AutoHotkey aka AHK.

AutoHotkey er et program der lader dig lave dine egne hotkeys og macros, med et ret simpelt programmerings sprog.

Her er et eksempel:

^!c::
				IfWinExist Lommeregner
					WinActivate
else
	run calc.exe
return

Denne script lader mig starte lommeregneren ved at trykke Ctrl+Alt+C, og hvis lommeregneren allerede kører, men ikke er aktiv, vil den gøre lommeregneren aktiv.

Dette er en ekstremt simpel script, og kan let laves om så den gør det samme ved andre programmer / filer, bare ved at erstatte værdierne "Lommeregner" og "calc.exe".
- Jeg skal nok komme ind på dette senere.

Man kan også styre rundt med og manipulere musen, så AHK kan også bruges til automatiske fremlæggelser, eller sjov og spas med venner.

Man kan lave meget mere med det, siden det bruger alle din computers indbyggede kommandoer, og mere til, men jeg dækker bare til det normale brug.

Hvis ønsket er der en bedre forklaring på deres hjemmeside (engelsk)

• Download
• Forum (engelsk)
• Wiki
• Notepad++
• Quick-start tutorial
• Liste med kommandoer
• Liste med hotkeys

Så nu har i både download links, lister med de mange kommandoer og hotkeys, og en nem tutorial! Men jeg vil da gerne hjælpe lidt, så jeg kommer lige med nogle forklaringer på hvad det egentlig er de forskellige ting betyder, og hvad de gør.
- Jeg smider også nogle brugbare scripts ind tilsidst.

Hvis i vil se et eksempel på en lidt mere avanceret script, kan i kigge her.

Så altså, hvad betyder det der står i den script jeg nævnte i starten? Lad os analysere det.

Facts:

• Alle originale koder står i

  CODE FORMAT

  format.
• Eksempler med simpel forklaring står i

  QUOTE FORMAT

• Koder der ikke er i nogen af de bokse, vil stå med fed.
• Alt redigeres i Notepad eller Notepad++, og gemmes som ".ahk" filer.
• Det er muligt at have mere end en script i en .ahk fil, dog frarådes det at have for mange.
• Alle aktive .ahk filer vil poppe op nede i højre hjørne ved uret, hvis ikke attributen #NoTrayIcon er aktiv.
• Alle aktive .ahk filer kan redigeres, pauses, suspenderes og reloade ved et højre klik på den specifikke .ahk fil.
• Efter redigering af en .ahk skal der reloades.

Vi lægger ud med at bestemme os for hvordan vores script skal aktiveres, i dette tilfælde valgte jeg Ctrl+Alt+C.

BEMÆRK: Dette skal kun bruges hvis scripten skal aktiveres manuelt.

^!c::

Grunden til at der står "^!c", er fordi AHK oversætter forskellige tegn eller betydninger til bestemte taster, eller handlinger.

(Fuld liste kan findes ovenfor)

^ = Ctrl
! = Alt
c = c
:: = start script

Den næste del går ind og tjekker om vinduet "Lommeregner" eksistere, og hvis ja, aktiveres vinduet.

				IfWinExist Lommeregner
					WinActivate

IfWinExist går ind og tjekker om et vindue eksistere, man kan specificere dette vindue ved at skrive navnet på det bestemte vindue lige efter, hvilket fungere fint hvis man vil lave en script som denne, hvor vinduet aldrig skifter titel.

WinActivate aktivere et specifikt vindue. Vinduet kan vælges enten med en IfWin-?- kommando, eller det kan bare skrives efter WinActivate.

IfWin-?- (vindue man vil manipulere)
Win-?- (? = hvad man vil gøre med det bestemte vindue)

De næste to linjer bliver kun aktiveret hvis IfWinExist kommandoen havde resultatet nej, og i det tilfælde startes lommeregneren.

else
	run calc.exe

else er en kode der kan bruges i sammenhæng med If kommandoen. Dette vil sige at hvis den valgte If kommando får et negativt resultat, går den videre til det der står efter else kommandoen. Det er et simpelt "enten eller" valg.

run burde forklare sig selv. Den starter et bestemt program eller åbner en bestemt fil. For for at finde ud af hvad programmets genvej er, kan du åbne det og tjekke "process" tabben i din jobliste. For at åbne filer kopiere du bare stien hen til den valgte fil som f.eks. "X:\Users\Brugernavn\Documents\fil_du_vil_åbne.filt ype".

else (aktivere koden under hvis en tidligere If kommando var negativ)
run (program / sti til fil)

Og så til den sidste...

return

return er egentlig bare en afslutning på en script med mere end en kode, hvilket betyder at du ikke behøver den hvis din kode f.eks. bare er:

^!c:: run calc.exe

Altså ..

^!c:: IfWinExist Lommeregner (1. kode)
WinActivate (2. kode)
return (bruges fordi der er to linjer med kode)

^!c:: run calc.exe
(return bruges ikke, fordi der kun er en linje med kode)

Grunden til at man har return kommandoen, er fordi der sagtens kan være mere end en script i en AHK fil.

Nu skulle i have en idé om hvor simpelt det egenligt er, men jeg vil dog foreslå at i går igennem deres quick-start tutorial.

For optimal ydelse og brugervenlighed vil jeg foreslå i giver jeres scripts disse attributter:

#NoEnv

Sørger for at scripten ikke læser tomme værdier.

#Persistent

Sørger for at scripten ikke lukker medmindre scriptens process bliver lukket, eller koden ExitApp indtræffer.

#SingleInstance force

Sørger for at der kun kan køre en af den script på computeren.

Attributter tilføjes øverst i dokumentet som set her:

#NoEnv
#SingleInstance force
#Persistent

Script Start

Her er et par nyttige scripts til hverdags surfing. Håber i kan bruge dem.

BEMÆRK: Jeg har IKKE lavet alle disse scripts.

************************************************** ************************************************** ****

AltTabMousewheel

~LButton & WheelUp::		AltTab
~LButton & WheelDown::		ShiftAltTab

Hold venstre museknap nede og scroll med hjulet.

************************************************** ************************************************** ****

Her er en jeg lige hurtigt lavede, som kan hjælpe med at rette op på det langsomme højreklik hvis man bruger RightClicker

AutoDelete

^D::
	Click
	Send {DELETE}
			WinWaitActive, Slet
	Send {ENTER}
return

Hold musen over det der skal slettes, og tryk Ctrl+D.

************************************************** ************************************************** ****

Den her script er et MUST hvis du aktivt bruger AHK scripts.

MasterIcon

; Master TrayIcon to control all running instances of AutoHotkey

#Persistent
Menu, Tray, Icon, User32.DLL, 4
DetectHiddenWindows, On
SelfID := WinExist( A_ScriptFullPath " ahk_class AutoHotkey")
Menu, Tray, NoStandard
WinGet, AList, List, ahk_class AutoHotkey

Loop %AList% {
               ID := AList%A_Index%
               IfEqual, ID, %SelfID%, Continue
 
               WinGetTitle, ATitle, ahk_id %ID%
               StringSplit, ATitle, ATitle, -
               SplitPath, ATitle1, Name
               StringUpper, Name, Name

               Menu,%Name%,Add, %A_Index%:Reload , MenuChoice
               Menu,%Name%,Add, %A_Index%:Edit   , MenuChoice
               Menu,%Name%,Add, %A_Index%:Pause  , MenuChoice
               Menu,%Name%,Add, %A_Index%:Suspend, MenuChoice
               Menu,%Name%,Add, %A_Index%:Exit   , MenuChoice
               Menu, Tray, Add, %Name%, :%Name%
             }

Menu, Tray, Add
Menu, Tray, Add, Quick Reload, Reload
Menu, Tray, Add
Menu, Tray, Default, Quick Reload
Menu, Tray, Click, 1
Menu, Tray, Standard

Return

MenuChoice:
  StringSplit, F,A_ThisMenuItem, :
  IfEqual,F2,Reload , PostMessage,0x111,65400,0,,% "ahk_id" AList%F1%
  IfEqual,F2,Edit   , PostMessage,0x111,65401,0,,% "ahk_id" AList%F1%
  IfEqual,F2,Pause  , PostMessage,0x111,65403,0,,% "ahk_id" AList%F1%
  IfEqual,F2,Suspend, PostMessage,0x111,65404,0,,% "ahk_id" AList%F1%
  IfEqual,F2,Exit   , PostMessage,0x111,65405,0,,% "ahk_id" AList%F1%
Return

Reload:
  Reload

Med den kan du tilføje attributten #NoTrayIcon til dine scripts, dette sørger for at kun MasterIcon kan ses, og du kan redigere, suspendere etc. dine andre scripts bare ved at højreklikke på den.

************************************************** ************************************************** ****

Med denne script kan din højre museknap nu få op til 3 funktioner !
BEMÆRK: Dette vil gøre normalt højreklik lidt langsommere

RightClicker

#NoEnv
#SingleInstance force

Rbutton::
keywait, rbutton, t0.5
if errorlevel = 1
{
;		Right click hold =
MsgBox Right click hold
;
return
}
else
keywait, rbutton, d, t0.5
if errorlevel = 0
{
;		Double right click =
MsgBox Double right click
;
return
}
else
;		Normal right click
mouseclick, right
;
return

Bare rediger funktionerne efter eget behov, som vist her:

{
;		Right click hold =
Send {ctrl down}
Send c
Send {ctrl up}
;
return
}

{
;		Double right click =
Send {ctrl down}
Send v
Send {ctrl up}
;
return
}

************************************************** ************************************************** ****

Linux populære "alt drag" funktion, nu til windows!

AltDrag

#NoEnv
#SingleInstance force

!LButton::
CoordMode, Mouse  ; Switch to screen/absolute coordinates.
MouseGetPos, EWD_MouseStartX, EWD_MouseStartY, EWD_MouseWin
WinGetPos, EWD_OriginalPosX, EWD_OriginalPosY,,, ahk_id %EWD_MouseWin%
WinGet, EWD_WinState, MinMax, ahk_id %EWD_MouseWin% 
if EWD_WinState = 0  ; Only if the window isn't maximized 
    SetTimer, EWD_WatchMouse, 10 ; Track the mouse as the user drags it.
return

EWD_WatchMouse:
GetKeyState, EWD_LButtonState, LButton, P
if EWD_LButtonState = U  ; Button has been released, so drag is complete.
{
    SetTimer, EWD_WatchMouse, off
    return
}
GetKeyState, EWD_EscapeState, Escape, P
if EWD_EscapeState = D  ; Escape has been pressed, so drag is cancelled.
{
    SetTimer, EWD_WatchMouse, off
    WinMove, ahk_id %EWD_MouseWin%,, %EWD_OriginalPosX%, %EWD_OriginalPosY%
    return
}
; Otherwise, reposition the window to match the change in mouse coordinates
; caused by the user having dragged the mouse:
CoordMode, Mouse
MouseGetPos, EWD_MouseX, EWD_MouseY
WinGetPos, EWD_WinX, EWD_WinY,,, ahk_id %EWD_MouseWin%
SetWinDelay, -1   ; Makes the below move faster/smoother.
WinMove, ahk_id %EWD_MouseWin%,, EWD_WinX + EWD_MouseX - EWD_MouseStartX, EWD_WinY + EWD_MouseY - EWD_MouseStartY
EWD_MouseStartX := EWD_MouseX  ; Update for the next timer-call to this subroutine.
EWD_MouseStartY := EWD_MouseY
return

Er du for doven til selv at gå ind på google og søge? Lad en script gøre det for dig!

GoogleHighlighted

SendMode Input
RegRead, OutputVar, HKEY_CLASSES_ROOT, 

http\shell\open\command
StringReplace, OutputVar, OutputVar,"
SplitPath, OutputVar,,OutDir,,OutNameNoExt, 

OutDrive
browser=%OutDir%\%OutNameNoExt%.exe

^g::
{
   BlockInput, on
   prevClipboard = %clipboard%
   clipboard =
   Send, ^c
   BlockInput, off
   ClipWait, 2
   if ErrorLevel = 0
   {
      searchQuery=%clipboard%
      GoSub, GoogleSearch
   }
   clipboard = %prevClipboard%
   return
}

GoogleSearch:
   StringReplace, searchQuery, searchQuery, `r`n, 

%A_Space%, All
   Loop
   {
      noExtraSpaces=1
      StringLeft, leftMost, searchQuery, 1
      IfInString, leftMost, %A_Space%
      {
         StringTrimLeft, searchQuery, searchQuery, 1
         noExtraSpaces=0
      }
      StringRight, rightMost, searchQuery, 1
      IfInString, rightMost, %A_Space%
      {
         StringTrimRight, searchQuery, searchQuery, 

1
         noExtraSpaces=0
      }
      If (noExtraSpaces=1)
         break
   }
   StringReplace, searchQuery, searchQuery, \, 

`%5C, All
   StringReplace, searchQuery, searchQuery, %

A_Space%, +, All
   StringReplace, searchQuery, searchQuery, `%, 

`%25, All
   IfInString, searchQuery, .
   {
      IfInString, searchQuery, +
         Run, %browser% 

http://www.google.com/search?hl=en&q=%

searchQuery%
      else
         Run, %browser% %searchQuery%
   }
   else
      Run, %browser% 

http://www.google.com/search?hl=en&q=%

searchQuery%
return

Bare marker noget tekst og tryk Ctrl+G.

************************************************** ************************************************** ***

Her er en brugbar script til Minecraft !

MinecraftHackery

; Minecraft Hackery v1.0
; Author:	Justin Ribeiro <justin@justinribeiro.com>
; Website:	http://www.justinribeiro.com/
; Edit by Wizhi aka. GoC
;
; 	Additional Credits:
;		1) F1/F2 mappings from Desi Quintans' Minecraft Remaps v2.1 (http://www.desiquintans.com)
;		2) autopilot code from jaceguay (http://www.autohotkey.com/forum/topic59506.html)
;		3) autocrouch from avien (http://www.minecraftforum.net/viewtopic.php?f=3&t=60032)
;		4) item id key image from Marvin http://marvk.net/?page_id=184
;		5) initial GUI mocked up with SmartGUI Creator 4.0 (http://www.autohotkey.com/download/)
;		6) AutoHotKey.  Seriously, my desktop would not be useable without you.
;
;	Script Function:
;  		The following will only apply inside the Minecraft window:
;			1) From Desi's Remaps: F1 toggles hold-left-click. Handy for breaking lots of blocks or mining 

obsidian.
;			2) From Desi's Remaps: F2 toggles hold-W, making you move forward automatically. Use with 

F1 for automated mining action!
;			3) F3 toggles hold-s, making you move backward automatically.
;			4) F4 prompts for itemid, for use as OP in SMP: make sure to set player var
;			5) Ctrl-R toggles crouching.
;
;	Script Presumes:	
;		The script makes the following assumptions (which you can change if you like in the code)
;			1) Talk is mapped to "t"
;			2) Walk is mapped to "w"
;			3) Backwards Walk is mapped to "s"
;			4) Crouch is mapped to LShift
;
;	Setup:
;		1) Go download the item key image and remember the path where you put it (get image: 

http://marvk.net/?page_id=184)
;		2) Set the vars for your player name and the item key image in the SetMineCraftDefaults() function
;		3) ???
;		4) Profit

#NoEnv
#InstallKeybdHook
#SingleInstance
SendMode Input
SetWorkingDir %A_ScriptDir%
SetTitleMatchMode, 3

; This function sets the global vars that are needed by the rest of the app
SetMineCraftDefaults()
{
	; Do not remove
	global 
	
	; Set your default user
	dfplayerhandle := "<Indsæt Minecraft navn her>"
	
	; Image used to be in the Minecraft wiki, can get from original source: http://marvk.net/?page_id=184
	dfitemkeyimg := "<Indsæt sti til Block Value her>"
	
	dfquantity := 64
	dfloop := 1
}	

#IfWinActive, Minecraft
{
	; The following autopilot code was borrowed from jaceguay at http://www.autohotkey.com/forum/topic59506.html
	F1::Send % "{LButton " ((Cnt := !Cnt) ? "Down}" : "Up}" )
	F2::Send % "{w " ((Cnt2 := !Cnt2) ? "Down}" : "Up}" )
	
	; Walk backwards
	F3::Send % "{s " ((Cnt2 := !Cnt2) ? "Down}" : "Up}" )
	
	; Ctrl-r for autocrouch from avien at http://www.minecraftforum.net/viewtopic.php?f=3&t=60032
	^r::
	GetKeyState, state, Shift
	if state = D
	   Send {LShift Up}
	else
	   Send {LShift Down}
	return
	
	; The following is my GUI for giving items to either yourself or other players as an OP in SMP
	F4::Goto, GetSomeItem
	GetSomeItem:
		; Get the globals
		SetMineCraftDefaults()
		
		; We open a talk command line, otherwise Minecraft trips out
		SendInput t 
		
		; Start building the GUI
		; Initial GUI was mocked up with SmartGUI Creator 4.0
		Gui, +LastFound +AlwaysOnTop +ToolWindow +Border
		Gui, Font, s12, Arial

		; !!!! IMPORTANT !!!!!
		; Make sure you set the correct path to the image file here!
		Gui, Add, Picture, x15 y15 w300 h660 , %dfitemkeyimg%
		
		Gui, Add, GroupBox, x320 y15 w305 h370 , Pick your Poison
		Gui, Add, Text, x330 y46 w290 h20 , Block ID
		Gui, Add, Edit, x330 y73 w66 h25 vitemid +Number +ToolTip,
		Gui, Add, Text, x330 y112 w290 h20 , Antal
		Gui, Add, Edit, x330 y137 w65 h25 vsbquantity +Number +ToolTip,
		Gui, Add, Text, x330 y175 w290 h20 , Loop
		Gui, Add, Edit, x330 y205 w66 h25 vsbloop +Number +ToolTip,
		Gui, Add, Text, x330 y244 w290 h20 , Spiller
		Gui, Add, Edit, x330 y276 w247 h25 vsbplayerhandle +ToolTip,
		Gui, Add, Text, x400 y137 w220 h20 , (default = 64`, max = 64)
		Gui, Add, Text, x400 y204 w220 h20 , (default = 1)
		Gui, Add, Button, x330 y320 w130 h55 , Deliver
		Gui, Add, Button, x470 y320 w130 h55 , Cancel

		Gui, Add, GroupBox, x320 y400 w305 h285 , Credits
		Gui, Add, Text, x330 y430 w290 h45 , Original af Justin Ribeiro
		Gui, Add, Text, x330 y450 w290 h45 , justin@justinribeiro.com
		Gui, Add, Text, x330 y470 w290 h45 , www.justinribeiro.com/
		Gui, Add, Text, x330 y490 w290 h45 , ---------------------------------------------------------
		Gui, Add, Text, x330 y510 w290 h45 , Block Value billede af Marvin
		Gui, Add, Text, x330 y530 w290 h45 , http://marvk.net/
		Gui, Add, Text, x330 y550 w290 h45 , ---------------------------------------------------------
		Gui, Add, Text, x330 y570 w290 h45 , Redigeret af Wizhi aka. GoC
		Gui, Add, Text, x330 y590 w290 h45 , lortenlars@hotmail.com
		Gui, Add, Text, x330 y610 w290 h45 , ---------------------------------------------------------
		Gui, Add, Text, x330 y630 w290 h45 , Originale scripts kan findes i .ahk filen
		Gui, Add, Text, x330 y650 w290 h45 , ************************************************
		Gui, Show, x100 y100 h700 w650, MinecraftHackery
		Return

		GuiClose:
			SendInput {Esc}
			Gui, Destroy
		Return		
		
		ButtonCancel:
			SendInput {Esc}
			Gui, Destroy
		Return
		
		ButtonDeliver:
			; Get our vars from the form
			GUI, Submit
			
			; Switch back to the minecraft window
			WinActivate, Minecraft
			
			; We close the talk screen as a safety
			SendInput {Esc}
			
			; Which user are we targeting
			if (sbplayerhandle)
			{
				player := sbplayerhandle
			}
			else
			{
				player := dfplayerhandle
			}
			
			; Which quantity are we going to use
			if (sbquantity)
			{
				quantity := sbquantity
			}
			else
			{
				quantity := dfquantity
			}
			
			; How many loops
			; Note, we add +1 because of A_Index in the loop always starts at 1 and not 0
			if (sbloop)
			{
				loopnumber := sbloop + 1
			}
			else
			{
				loopnumber := dfloop + 1
			}
			
			; We run our loop to give us some stuff
			while A_Index <= loopnumber
			{
				; We send the commands to the minecraft window
				SendInput t
				SendInput #/give %player% %itemid% %quantity% {Enter}
				
				; If we don't sleep for a half second, the loop goes way too fast
				Sleep, 500
			}

			Gui, Destroy
		Return    	    
	Return
}

Features:

• F1: Automining (holder venstre museknap inde)
• F2: Autowalk (holder W inde)
• F3: "Moonwalk" (holder S inde)
• F4: "/give" command til OPs, nu i en simpel GUI

For at sætte Minecraft Hackery op så "/give/ GUIen fungere skal i gøre som følgende:

1. Download dette billede
   
2. Indsæt bruger info, som vist i dette eksempel
   
   

   {
   	; Do not remove
   	global 
   	
   	; Set your default user
   	dfplayerhandle := "Wizhi"
   	
   	; Image used to be in the Minecraft wiki, can get from original source: http://marvk.net/?page_id=184
   	dfitemkeyimg := "C:\Users\Bruger\Desktop\MineCraft\ItemID.png"
   	
   	dfquantity := 64
   	dfloop := 1
   }

3. ???
4. Profit

************************************************** ************************************************** ****

More to come..

Håber det kunne bruges.

Kom endelig med nogle scripts hvis i har nogen !

EDIT: Man behøver på ingen måde at kunne forstå koderne for at få en script til at virke. Bare copy paste ind i et notepad og gem det som en .ahk fil og dobbelt klik på den.

- GoC

[Soyaman]

Det må jeg sgu sige.
Selvom jeg ikke forstår halvdelen af det, Må jeg sige det virkelig er en fed guide.

+rep fra mig.
Keep up the good work!

[God of Cheating]

Originalt skrevet af Soyaman

Det må jeg sgu sige.
Selvom jeg ikke forstår halvdelen af det, Må jeg sige det virkelig er en fed guide.

+rep fra mig.
Keep up the good work!

Tak tak Soya.

Tog mig en 2 timer at få samlet info og få det hele lavet på en måde så alle (eller næsten lol) kunne forstå det.

[lundahl]

Forstår heller ikke selv så meget af det, men det jeg forstår bliver fortalt rigtig god . Skulderklap.

[Taizun]

Det er sjovt du vælger at fortælle om AHK netop nu
Inde på minecraft.dk (Som også ejes af SnydAdmin) er det ikke længe siden at vi har snakket om scripts til AHK som kunne gøre spillet en del nemmere for os.

Personligt er jeg ikke god til at lave disse scripts selv, medmindre de er super-simple. Men heldigvis er der nogle der har talent for det, og virkelig kan præstere at lave nogle virkelig nyttige scripts som man kan bruge "on a daily basis" for at gøre sit arbejde ved en computer meget nemmere.

Super fedt GoC!

[God of Cheating]

Originalt skrevet af Taizun

Det er sjovt du vælger at fortælle om AHK netop nu
Inde på minecraft.dk (Som også ejes af SnydAdmin) er det ikke længe siden at vi har snakket om scripts til AHK som kunne gøre spillet en del nemmere for os.

Personligt er jeg ikke god til at lave disse scripts selv, medmindre de er super-simple. Men heldigvis er der nogle der har talent for det, og virkelig kan præstere at lave nogle virkelig nyttige scripts som man kan bruge "on a daily basis" for at gøre sit arbejde ved en computer meget nemmere.

Super fedt GoC!

Sjovt nok fandt jeg AHK da jeg sad og ledte efter nogle Minecraft plugins og mods !

Jeg fandt faktisk nogle scripts der er ekstremt brugbare i Minecraft, kan godt lige poste dem.

EDIT: Så har jeg posted MinecraftHackery, et dejligt værktøj til Minecraftere

[Taizun]

Originalt skrevet af God of Cheating

Sjovt nok fandt jeg AHK da jeg sad og ledte efter nogle Minecraft plugins og mods !

Jeg fandt faktisk nogle scripts der er ekstremt brugbare i Minecraft, kan godt lige poste dem.

EDIT: Så har jeg posted MinecraftHackery, et dejligt værktøj til Minecraftere

Det skal selvfølgelig også lige nævnes at denne type scripts tillader vi ikke på Minecraft.dk, da de går ind under "automatiserede scripts". Så hvis nogen af jer hyppigt spiller på minecraft.dk vil jeg stærkt fraråde jer at benytte jer af det nye Minecraft script GoC har tilføjet til listen.

Men det er altid et fint supplement til listen, da netop sådan et scripts kan bruges både i Singleplayer og Multiplayer

[themaster]

Holy god hvorfor har jeg ikke set det her? +rep fra mig
Det er virkelig en fed tutorial du har lavet dig. Jeg kommer dog ikke til at bruge den.

[mathias66]

jeg bruger selv "workshop macro"...

syntes selv det er simplere

[SnydAdmin]

very cool stuff! Rep sendt